Menampilkan Tombol Maximize Dan Minimize Di Userform VBA Excel

Apliaksi Excelku. Seperti yang sudah kita ketahui bersama, pada saat kita membuat sebuah userform didalam lembar kerja Visual Basic Ms. Excel tidak terdapat tombol Maximize dan Minimize hanya ada tombol Close (x) saja. Dan pada kesempatan ini Saya akan membagikan sebuah tutorial sederhana mengenai Cara Untuk Menampilkan Tombol Maximize Dan Minimize Di Userform VBA Excel, tentunya sebagai bahan pembelajaran kita bersama agar menambah ilmu mengenai VBA Excel.

Dan berikut ini langkah-langkah dalam menampilkan tombol maximize dan minimize didalam userform VBA Ms. Excel :

1. Membuat Sebuah Userform

Didalam lembar kerja Aplikasi Ms. Excel klik pada menu Developer, kemudian klik lagi pada Visual Basic, atau bisa juga menggunakan tombol kombinasi ALT+F11 pada keyboard

Kemudian didalam halaman Visual Basic Ms. Excel klik pada menu Insert kemudian klik lagi pada Useform, kemudian silahkan tentukan sendiri tinggi dan lebar dari Userform (sesuaikan dengan kebutuhan). Contohnya seperti pada gambar di bawah ini :

Tahap pembuatan userform sudah selesai.

2. Menyisipkan Kode/Script Macro

Ada 2 (dua) langkah dalam menyisipkan kode/script Macro, yaitu :

a. Menyisipkan Kode/Script Macro Didalam Module

Untuk menyisipkan kode/script Macro kedalam module, pastinya kita harus menyisipkan module terlebih dulu, dan caranya adalah : klik pada menu Insert kemudian klik lagi pada module, selanjutnya silahkan Copas kode/script Macro di bawah ini kedalam module tersebut :

Option Explicit
Rem Auth : ExcelNoob.com
'https://aplikasiexcelku.blogspot.com
Public Const GWL_STYLE As Long = -16
Public Const WS_MINIMIZEBOX = &H20000
Public Const WS_MAXIMIZEBOX = &H10000
Public Const WS_FULLSIZING = &H70000
#If VBA7 And Win64 Then
Public Declare PtrSafe Function FindWindowA& Lib "user32" _
        (ByVal lpClassName$, ByVal lpWindowName$)
Public Declare PtrSafe Function GetWindowLongA& Lib "user32" _
        (ByVal hwnd&, ByVal nIndex&)
Public Declare PtrSafe Function SetWindowLongA& Lib "user32" _
        (ByVal hwnd&, ByVal nIndex&, ByVal dwNewLong&)
#Else
Public Declare Function FindWindowA& Lib "user32" _
        (ByVal lpClassName$, ByVal lpWindowName$)
Public Declare Function GetWindowLongA& Lib "user32" _
        (ByVal hwnd&, ByVal nIndex&)
Public Declare Function SetWindowLongA& Lib "user32" _
        (ByVal hwnd&, ByVal nIndex&, ByVal dwNewLong&)
#End If
Public Sub InitMaxMin(mCaption As String, _
                    Optional Max As Boolean = True, _
                    Optional Min As Boolean = True, _
                    Optional Sizing As Boolean = True)
Dim hwnd As Long
hwnd = FindWindowA(vbNullString, mCaption)
If Min Then SetWindowLongA hwnd, _
    GWL_STYLE, GetWindowLongA(hwnd, GWL_STYLE) Or WS_MINIMIZEBOX
If Max Then SetWindowLongA hwnd, _
    GWL_STYLE, GetWindowLongA(hwnd, GWL_STYLE) Or WS_MAXIMIZEBOX
If Sizing Then SetWindowLongA hwnd, _
    GWL_STYLE, GetWindowLongA(hwnd, GWL_STYLE) Or WS_FULLSIZING
End Sub

Untuk proses menyisipkan kode/script Macro didalam module sudah selesai. Silahkan tutup module tersebut.

b. Menyisipkan Kode/Script Macro Kedalam Userform

Pertama-tama klik kanan pada Userform yang sudah kita buat sebelumnya, kemudian klik lagi pada pada View Code, langkah selanjutnya adalah Copas kode/script Macro di bawah ini kedalam Userform tadi :

Private Sub UserForm_Initialize()
'https://aplikasiexcelku.blogspot.com
InitMaxMin Me.Caption
End Sub

Selesai.

Untuk melihat hasilnya, silahkan klik pada tombol Run atau bisa juga dengan menekan tombol F5 pada keyboard. Dan hasilnya adalah akan muncul tombol Maximize dan Minimize didalam Userform tadi. Mungkin hanya itu saja yang bisa Saya sampaikan pada kesempatan kali ini, dan jika Sobat Blogger ingin mengunduh/download file samplenya bisa mengunduh/download melalui link yang sudah Saya sediakan di akhir artikel/postingan ini. Mudah-mudahan apa yang sudah Saya sampaikan pada kesmepatan kali ini bisa bermanfaat untuk kita semuanya. Sekian, terimakasih, dan salam belajar.

Download Sample File Tombol Maximize Dan Minimize UserForm

Aplikasi Excelku

Menampilkan Tombol Maximize Dan Minimize Di Userform VBA Excel

Post a Comment for "Menampilkan Tombol Maximize Dan Minimize Di Userform VBA Excel"